puzzle-quest/scenes/Global.gd

extends Control

const TICKS_TIME_MAX = 100 # msec

onready var current_scene = null
onready var current_scene_int = null
onready var loader = null
onready var wait_frames = 1
onready var database = null
onready var table_levels = null

var msetting = preload("res://db/MSetting.gd")
var setting = null

func _ready():
	_initialize_database()
	_initialize_setting()
	_initialize_current_scene()

func _initialize_setting():
	setting = msetting.new()
	
	apply_language(translate_int_to_locale(get_setting_language()))
	apply_resolution()
	apply_fullscreen()

func translate_int_to_locale(id):
	var lang = "en_GB"
	
	if id == 0:
		lang = "en_GB"
	
	if id == 1:
		lang = "fr_FR"
		
	return lang

func apply_language(local):
	TranslationServer.set_locale(local)

func apply_resolution():
	var screen_size = Vector2(get_setting_resolution()[0], get_setting_resolution()[1])
	var margin_size = Vector2(0, 0)
	get_viewport().set_size_override(true, screen_size, margin_size)

func apply_fullscreen():
	OS.set_window_fullscreen(get_setting_fullscreen())

func goto_scene(path):
	print("[global#goto_scene] : "+String(path))
	loader = ResourceLoader.load_interactive(path)
	if loader == null:
		print("Error loading ....")
		return
	
	set_process(true)
	current_scene.queue_free()
	wait_frames = 1
	Loading.get_node("VBoxContainer/ProgressBar").set_max(loader.get_stage_count())

func get_setting_language():
	return setting.get_langue()

func set_setting_language(value):
	setting.set_langue(value)
	apply_language(translate_int_to_locale(value))

func get_setting_gyrosocpe():
	return setting.get_gyroscope()

func set_setting_gyroscope(value):
	setting.set_gyroscope(value)

func get_setting_ambient_sound():
	return setting.get_ambient_sound()

func set_setting_ambient_sound(value):
	setting.set_ambient_sound(value)

func get_setting_resolution():
	return setting.get_resolution()

func set_setting_resolution(value):
	setting.set_resolution(value)
	apply_resolution()

func get_setting_fullscreen():
	return setting.get_fullscreen()

func set_setting_fullscreen(value):
	setting.set_fullscreen(value)
	apply_fullscreen()

func _process(_delta):
	print("[global#_process]")
	if loader == null:
		set_process(false)
		return
	
	if wait_frames > 0:
		wait_frames -= 1
	
	var tick = OS.get_ticks_msec()
	
	# Use "TICKS_TIME_MAX" to control for how long we block this thread
	while OS.get_ticks_msec() < tick + TICKS_TIME_MAX:
		var err = loader.poll()
		
		if err == ERR_FILE_EOF: # Finished loading.
			_set_new_scene()
			break
		elif err == OK:
			_update_progress()
		else:
			loader = null
			break

## PRIVATE
func _initialize_current_scene():
	print("[global#_initialize_current_scene]")
	var root = get_tree().get_root()
	current_scene = root.get_child(root.get_child_count() - 1)
	
	if current_scene.name != "Main":
		get_node("/root/Loading").hide()

func _initialize_database():
	print("[global#_initialize_database]")
	var database_manager = load(gddb_constants.c_addon_main_path + "core/db_man.gd").new()
	var db_id = database_manager.load_database("res://db/ahog.json")
	
	if db_id == gddb_types.e_db_invalid_file:
		print("[global#_initialize_database] Error invalid database file !")
		OS.set_exit_code(1)
	
	if db_id == gddb_types.e_db_invalid_ver:
		print("[global#_initialize_database] Error invalid database version !")
		OS.set_exit_code(1)
	
	database = database_manager.get_db_by_id(db_id)
	table_levels = database.get_table_by_name("levels")

func _update_progress():
	Loading.visible = true
	Loading.get_node("VBoxContainer/ProgressBar").set_value(loader.get_stage())

func _set_new_scene():
	var resource = loader.get_resource()
	loader = null
	current_scene = resource.instance()
	get_node("/root").add_child(current_scene)
	get_node("/root/Loading").hide()