@tool
extends SceneTree

# One-shot migration tool: walk every .material file, fix Godot 3 shader code
# to Godot 4 syntax, save back.
#
# Run with: godot --headless --script scripts/migrate_shaders.gd

const REPLACEMENTS := [
	["depth_draw_alpha_prepass", "depth_prepass_alpha"],
	["hint_color", "source_color"],
	["hint_albedo", "source_color"],
	["hint_black_albedo", "source_color"],
	["hint_white", ""],
	["hint_black", ""],
	["hint_aniso", "hint_anisotropy"],
	["NORMALMAP", "NORMAL_MAP"],
]

func _init() -> void:
	var fixed := 0
	var checked := 0
	for path in _find_materials("res://assets"):
		checked += 1
		var mat = ResourceLoader.load(path, "", ResourceLoader.CACHE_MODE_IGNORE)
		if mat == null:
			continue
		if mat is ShaderMaterial and mat.shader != null:
			var old_code: String = mat.shader.code
			var new_code := old_code
			for pair in REPLACEMENTS:
				new_code = new_code.replace(pair[0], pair[1])
			if new_code != old_code:
				mat.shader.code = new_code
				var err = ResourceSaver.save(mat, path)
				if err == OK:
					fixed += 1
					print("FIXED ", path)
				else:
					push_error("Failed to save " + path + " (err=" + str(err) + ")")
	print("Done. checked=", checked, " fixed=", fixed)
	quit()

func _find_materials(dir_path: String) -> Array:
	var result := []
	var dir = DirAccess.open(dir_path)
	if dir == null:
		return result
	dir.list_dir_begin()
	var name = dir.get_next()
	while name != "":
		if name == "." or name == "..":
			name = dir.get_next()
			continue
		var sub = dir_path + "/" + name
		if dir.current_is_dir():
			result.append_array(_find_materials(sub))
		elif name.ends_with(".material") or name.ends_with(".tres"):
			result.append(sub)
		name = dir.get_next()
	return result