extends Control

export (PackedScene) var template = load("res://scenes/levels/Template.tscn")

onready var mlevel = load("res://db/MLevel.gd")

func _ready():
	_apply_scenes()

## PRIVATE
func _apply_scenes():
	for row_index in range(0, Global.database.get_table_by_name("levels").m_rows_count):
		_apply_scene(mlevel.new(row_index), 0)

func _build_path(name):
	return "MarginContainer/HBoxContainer/"+name

func _build_method(name):
	return "_on_"+name.to_lower()+"_pressed"

func _load_scene(name):
	var template_instance = template.instance()
	template_instance.set_name(name)
	
	return template_instance

func _load_texture(thumbnail):
	return load(thumbnail)

func _apply_scene(level, index):
	$MarginContainer/HBoxContainer.add_child(_load_scene(level.name()))
	var node = _build_path(level.name())
	
	_configure_select(level, node)
	_configure_reset(level, node, index)
	_configure_counter(level, node)

func _configure_select(level, node):
	var select = get_node(node+"/TextureRect/TextureButton")
	
	select.set_normal_texture(_load_texture(level.thumbnail()))
	select.connect("pressed", Event, _build_method(level.name()))

func _configure_reset(level, node, index):
	var reset = get_node(node+"/VBoxContainer/MarginContainer/ButtonReset")
	
	if int(level.object_finding()) == 0:
		reset.set_disabled(true)
		if reset.is_connected("pressed", Event, "_on_reset_level"):
			reset.disconnect("pressed", Event, "_on_reset_level")
	else:
		reset.set_disabled(false)
		reset.connect("pressed", Event, "_on_reset_level", [level, node, index, self])

func _configure_counter(level, node):
	var count = get_node(node+"/VBoxContainer/MarginContainer2/ButtonCount/Label")
	
	count.set_text(level.object_finding()+" / "+level.object_to_find())