puzzle-quest/scripts/Global.gd

extends Control

# Application root: async scene loading + reference to the loaded Database.

var current_scene: Node = null
var current_scene_int: int = -1
var wait_frames: int = 1
var database: RefCounted = null
var loaded: bool = false
var _loading_path: String = ""

@onready var animation: AnimationPlayer = Loading.get_node("AnimLoading")

func _ready() -> void:
	database = load("res://scripts/Database.gd").new().initialize()
	_initialize_current_scene()
	_initialize_loading_scene()

func _initialize_loading_scene() -> void:
	animation.animation_started.connect(Event._loading_is_started)
	animation.animation_finished.connect(Event._loading_is_finished)

func goto_scene(path: String) -> void:
	var err := ResourceLoader.load_threaded_request(path)
	if err != OK:
		push_error("[Global] failed to start threaded load for " + path)
		return
	_loading_path = path
	Loading.show()
	animation.play("BorderAnim")
	set_process(true)
	current_scene.queue_free()
	wait_frames = 1
	Loading.get_node("LoadingBare/VBoxContainer/HBoxContainer/ProgressBar").set_max(1.0)

func _process(_delta: float) -> void:
	if _loading_path == "":
		set_process(false)
		return
	if wait_frames > 0:
		wait_frames -= 1
	if not loaded:
		return
	var progress: Array = []
	var status := ResourceLoader.load_threaded_get_status(_loading_path, progress)
	match status:
		ResourceLoader.THREAD_LOAD_IN_PROGRESS:
			_update_progress(progress[0] if progress.size() > 0 else 0.0)
		ResourceLoader.THREAD_LOAD_LOADED:
			_set_new_scene()
		ResourceLoader.THREAD_LOAD_FAILED, ResourceLoader.THREAD_LOAD_INVALID_RESOURCE:
			push_error("[Global] failed to load " + _loading_path)
			_loading_path = ""

## PRIVATE
func _initialize_current_scene() -> void:
	var root := get_tree().get_root()
	current_scene = root.get_child(root.get_child_count() - 1)
	if current_scene.name != "Main":
		Loading.hide()

func _update_progress(value: float) -> void:
	Loading.visible = true
	Loading.get_node("LoadingBare/VBoxContainer/HBoxContainer/ProgressBar").set_value(value)

func _set_new_scene() -> void:
	var resource: PackedScene = ResourceLoader.load_threaded_get(_loading_path)
	_loading_path = ""
	current_scene = resource.instantiate()
	get_node("/root").add_child(current_scene)
	Loading.hide()